home *** CD-ROM | disk | FTP | other *** search
/ Aminet 1 (Walnut Creek) / Aminet - June 1993 [Walnut Creek].iso / aminet / util / gnu / fileutils_3_3.lha / fileutils-3.3 / configure.in < prev    next >
Text File  |  1992-08-01  |  3KB  |  126 lines
  1. dnl Process this file with autoconf to produce a configure script.
  2. AC_INIT(src/ls.c)
  3. AC_SUBST(PROGS)dnl
  4. AC_SUBST(LIBPROGS)dnl
  5. AC_PROG_CC
  6. AC_PROG_CPP
  7. AC_GCC_TRADITIONAL
  8. AC_PROG_RANLIB
  9. AC_AIX
  10. AC_MINIX
  11. AC_ISC_POSIX
  12. AC_HEADER_CHECK(limits.h, AC_DEFINE(HAVE_LIMITS_H))
  13. AC_MAJOR_HEADER
  14. AC_DIR_HEADER
  15. AC_RETSIGTYPE
  16. echo checking how to get list of mounted filesystems
  17. # SVR4
  18. AC_HEADER_EGREP(putmntent, sys/mnttab.h,
  19.   AC_DEFINE(MOUNTED_GETMNTENT2) mounted=1)
  20. if test -z "$mounted"; then
  21. # AIX.
  22. AC_TEST_CPP([#include <fshelp.h>], 
  23.   AC_DEFINE(MOUNTED_VMOUNT) mounted=1)
  24. fi
  25. if test -z "$mounted"; then
  26. # SVR3
  27. AC_TEST_CPP([#include <sys/statfs.h>
  28. #include <sys/fstyp.h>
  29. #include <mnttab.h>], 
  30.   AC_DEFINE(MOUNTED_FREAD_FSTYP) mounted=1)
  31. fi
  32. if test -z "$mounted"; then
  33. # 4.3BSD
  34. AC_TEST_CPP([#include <mntent.h>], 
  35.   AC_DEFINE(MOUNTED_GETMNTENT1) mounted=1)
  36. fi
  37. if test -z "$mounted"; then
  38. # 4.4BSD
  39. AC_HEADER_EGREP(MOUNT_UFS, sys/mount.h,  
  40.   AC_DEFINE(MOUNTED_GETMNTINFO) mounted=1)
  41. fi
  42. if test -z "$mounted"; then
  43. # Ultrix
  44. AC_TEST_CPP([#include <sys/fs_types.h>
  45. #include <sys/mount.h>],
  46.   AC_DEFINE(MOUNTED_GETMNT) mounted=1)
  47. fi
  48. if test -z "$mounted"; then
  49. # SVR2
  50. AC_TEST_CPP([#include <mnttab.h>],
  51.   AC_DEFINE(MOUNTED_FREAD) mounted=1)
  52. fi
  53.  
  54. echo checking how to get filesystem space usage
  55. # SVR4
  56. AC_TEST_CPP([#include <sys/statvfs.h>],
  57.   AC_DEFINE(STAT_STATVFS) space=1)
  58. if test -z "$space"; then
  59. # AIX
  60. AC_HEADER_EGREP(f_nlsdirtype, sys/statfs.h, 
  61.   AC_DEFINE(STAT_STATFS2_BSIZE) space=1)
  62. fi
  63. if test -z "$space"; then
  64. # SVR3
  65. AC_TEST_CPP([#include <sys/statfs.h>], 
  66.   AC_DEFINE(STAT_STATFS4) space=1)
  67. fi
  68. if test -z "$space"; then
  69. # 4.3BSD
  70. AC_TEST_CPP([#include <sys/vfs.h>],
  71.   AC_DEFINE(STAT_STATFS2_BSIZE) space=1)
  72. fi
  73. if test -z "$space"; then
  74. # 4.4BSD
  75. AC_HEADER_EGREP(MOUNT_UFS, sys/mount.h,
  76.   AC_DEFINE(STAT_STATFS2_FSIZE) space=1)
  77. fi
  78. if test -z "$space"; then
  79. # SVR2
  80. AC_TEST_CPP([#include <sys/filsys.h>],
  81.   AC_DEFINE(STAT_READ) space=1)
  82. fi
  83. if test -z "$space"; then
  84. # Ultrix
  85. AC_TEST_CPP([#include <sys/mount.h>],
  86.   AC_DEFINE(STAT_STATFS2_FS_DATA) space=1)
  87. fi
  88. if test -n "$mounted" && test -n "$space"; then
  89.   PROGS="$PROGS df" LIBOBJS="$LIBOBJS fsusage.o mountlist.o"
  90. fi
  91.  
  92. AC_UID_T
  93. AC_INT_16_BITS
  94. AC_STDC_HEADERS
  95. AC_UNISTD_H
  96. AC_USG
  97. AC_REPLACE_FUNCS(fnmatch mkdir mktime stpcpy strdup strstr rename)
  98. AC_HAVE_FUNCS(strerror fchmod ftime mkfifo)
  99. AC_COMPILE_CHECK(ftruncate, , [ftruncate();],
  100.   AC_DEFINE(HAVE_FTRUNCATE), ftruncate_missing=1)
  101. if test -n "$ftruncate_missing"; then
  102. AC_COMPILE_CHECK(fcntl emulation of ftruncate,
  103. [#include <sys/types.h>
  104. #include <fcntl.h>], [
  105. #if !defined(F_CHSIZE) && !defined(F_FREESP)
  106. chsize();
  107. #endif
  108. ], AC_DEFINE(HAVE_FTRUNCATE) LIBOBJS="$LIBOBJS ftruncate.o")
  109. fi
  110.  
  111. case "$LIBOBJS" in
  112. *rename.o*)
  113.   LIBPROGS="$LIBPROGS mvdir"
  114.   AC_DEFINE(MVDIR, \\\\\"\$(libdir)/mvdir\\\\\")
  115.   ;;
  116. esac
  117.  
  118. AC_VPRINTF
  119. AC_ALLOCA
  120. AC_ST_BLOCKS
  121. AC_UTIME_NULL
  122. AC_XENIX_DIR
  123. AC_IRIX_SUN
  124. AC_DYNIX_SEQ
  125. AC_OUTPUT(Makefile lib/Makefile src/Makefile man/Makefile)
  126.